-- stack: in.1
-- format: 8 (HyperCard 1)
-- flags: 0x1000 (none)
-- protect password hash: 0
-- maximum user level: 5 (scripting)
-- window: Rect(x1=0, y1=0, x2=0, y2=0)
-- screen: Rect(x1=0, y1=0, x2=0, y2=0)
-- card dimensions: w=0 h=0
-- scroll: x=0 y=0
-- background count: 5
-- first background id: 2629
-- card count: 269
-- first card id: 73808
-- list block id: 78382
-- print block id: 3363
-- font table block id: 0
-- style table block id: 0
-- free block count: 0
-- free size: 0 bytes
-- total size: 211008 bytes
-- stack block size: 6144 bytes
-- created by hypercard version: 0x01228000
-- compacted by hypercard version: 0x01228000
-- modified by hypercard version: 0x01228000
-- opened by hypercard version: 0x01228000
-- patterns[0]: 0x0000000000000000
-- patterns[1]: 0x0000220000002200
-- patterns[2]: 0x8800220088002200
-- patterns[3]: 0xCC003300CC003300
-- patterns[4]: 0xCC883322CC883322
-- patterns[5]: 0xFF00FF00FF00FF00
-- patterns[6]: 0xEECCBB33EECCBB33
-- patterns[7]: 0xFFCCFF33FFCCFF33
-- patterns[8]: 0xFFEEFFBBFFEEFFBB
-- patterns[9]: 0xFFFFFFBBFFFFFFBB
-- patterns[10]: 0x8010022001084004
-- patterns[11]: 0xFFFFFFFFFFFFFFFF
-- patterns[12]: 0x8822882288228822
-- patterns[13]: 0x1122448811224488
-- patterns[14]: 0xC4800C6843023026
-- patterns[15]: 0xB130031BD8C00C8D
-- patterns[16]: 0xAA00AA00AA00AA00
-- patterns[17]: 0x8822552288225522
-- patterns[18]: 0x8855225588552255
-- patterns[19]: 0x77DD77DD77DD77DD
-- patterns[20]: 0x8000000000000000
-- patterns[21]: 0xAA55AA55AA55AA55
-- patterns[22]: 0x5555555555555555
-- patterns[23]: 0x8244394482010101
-- patterns[24]: 0x8814224188412214
-- patterns[25]: 0x8080413E080814E3
-- patterns[26]: 0x22048C7422179810
-- patterns[27]: 0xBE808808EB088880
-- patterns[28]: 0x25C8328964244C92
-- patterns[29]: 0xA29C41BE2AC914EB
-- patterns[30]: 0x40A00000040A0000
-- patterns[31]: 0x8040200002040800
-- patterns[32]: 0xAA00800088008000
-- patterns[33]: 0xFF80808080808080
-- patterns[34]: 0x081C22C180010204
-- patterns[35]: 0xFF808080FF080808
-- patterns[36]: 0xF87422478F172271
-- patterns[37]: 0xBF00BFBFB0B0B0B0
-- patterns[38]: 0xFF7FBE5DA2418000
-- patterns[39]: 0xFAF5FAF5A050A050
-- checksum: 0x0
----- HyperTalk script -----
on openStack
  hide message box
  hide menubar
end openStack

on SetCard
  Global PrevTense
  if the number of buttons>2 then
    if the hilite of card button "Irregular 3" is true then
      show background field "Irregular Participle"
    else
      hide background field "Irregular Participle"
    end if
    if the hilite of card button "Irregular 1" is true and background field "Tense" is "Present" then
      DoIrregular Present
    else
      if the hilite of card button "Irregular 2" is true and background field "Tense" is "Preterite" then
        DoIrregular Preterite
      else
        RefreshScreen
        put Normal into PrevTense
      end if
    end if
  end if
end SetCard

on DoHighlight Menu, MenuButton
  Global MenuChoice
  get ((the mouseV - item 2 of the rect of bg field Menu) div 12) + 1
  put line it of background field Menu into MenuChoice
  get offset(return & MenuChoice & return, background field Menu) + 1
  Select char it to length(MenuChoice) + it of background field Menu
  wait 5
  hide background field Menu
  set hilite of bg button MenuButton to false
  send ManageResponse to background field Menu
end DoHighlight

on LocateMouse Menu, MenuButton
  if the visible of background field Menu is true then
    put false into Stop
    repeat while the Mouseh>=the left of bg field Menu and the mouseh<=the right of bg field Menu and the mousev>=the top of bg field Menu and the mousev<=the bottom of bg field Menu and Stop is false
      if the mouse is up then
        DoHighlight Menu, MenuButton
        put true into Stop
      end if
    end repeat
    hide background field Menu
    set hilite of background button MenuButton to false
  end if
end LocateMouse

on PutChoices Menu, MenuItems, MenuButton
  lock screen
  show background field Menu
  put MenuItems into background field Menu
  set hilite of bg button MenuButton to true
  unlock screen
end PutChoices

on FormVerb Tense
  put Tense into background field "SubjectRef"
  Conjugate background field Verb, Tense, Normal
  Refreshscreen
end FormVerb

on DoIrregular Tense
  Global PrevTense
  if PrevTense is not Tense then
    lock screen
    Refreshscreen
    unlock screen
  end if
  repeat with Subject=1 to 6
    set cursor to busy
    get Tense&Subject
    show background field it
  end repeat
  put Tense into PrevTense
end DoIrregular

on RefreshScreen
  Global PrevTense
  if PrevTense is "Present" or PrevTense is "Preterite" then
    repeat with Subject=1 to 6
      set cursor to busy
      get PrevTense&Subject
      hide background field it
    end repeat
  end if
end RefreshScreen